点击 👆 office研习社 👇 关注星标 ★ 不迷路
你好，我是小智。
前段时间给同学们介绍过Looku p函数的基本用法，相信大家都有所了解了。
其实，在Excel查找函数中，Lookup的查找功能超级强大，它可以实现很多Vlookup无法完成的查找。
今天我带大家一起盘点一下它的11种最经典用法。
1、 普通查找（已排序）
如果表格已按A列排序，可以直接用Lookup查找。
查找李伟所在的部门。
输入公式： =LOOKUP(E2,A2:A7,C2:C7)
2、 普通查找（未排序）
A列未排序的表格，就需要用0/的方法完成查找。
查找李伟所在的部门
输入公式：
=LOOKUP(1,0/(A2:A7=E2),C2:C7)
3、 查找最后
1）查找最后一个非数字字符
用一个汉字里排序靠后的「座」查找即可，当然你也可以用排序更后的生僻字，只是用的时候你很难打出来。
查找A列最后一个非数字字符
输入公式： =LOOKUP("座",A:A)
2）查找最后一个数字
用一个足够大的数字9E307即可。
查找B列最后一个数字
输入公式： =LOOKUP(9E+307,B:B)
3）查找最后一个非空内容
还是需要用0/模式查找
查找A列最后一个非空内容
输入公式：
=LOOKUP(1,0/(A1:A28<>""),A1:A28)
4）根据条件查找最后一个
公式和普通查找一样，但有多个符合条件时，lookup只会返回最后一个。
查找西瓜最后一次数量
输入公式：
=LOOKUP(1,0/(A2:A7=D2),B2:B7)
4、 区间查找
只要 数字已排序 ，可以进行区间匹配查找。
根据D2的销量查找对应区间提成
输入公式： =LOOKUP(D2,A:B)
5、 多条件查找
只需要在0/模式中多加条件即可
查找湖南的西瓜数量
输入公式： =LOOKUP(1,0/((B2:B7=F2)*(A2:A7=E2)),C2:C7)
6、 反向查找
根据部门查找姓名：
输入公式： =LOOKUP(F2,D2:D7,A2:A7)
7、 连续多列查找
输入公式： =LOOKUP($F2,$A:B)
8、 根据简称查全称
要借用find函数实现
如下图所示，要求根据信息表从上表中查找我的公众号全称。
输入公式：
=LOOKUP(9^9,FIND(A8,B2:B5),A2:A5)
9、 根据全称查简称
如下图所示，要求根据信息表从上表中查找培哥学堂的的关键词。
输入公式：
=LOOKUP(9^9,FIND(A10,A2:A5),B2:B5)
10、 包含查找
从给定的多个关键字中，从字符串中查找包括其中一个
现需要在B列把公众号全称的关键词分别提取出来，关键词有：小何、培哥、讲师、指南
输入公式：
=LOOKUP(9^9,FIND({"小何","培哥","讲师","指南"},A2),{"小何","培哥","讲师","指南"})
11、 数字提取
1）数字提取（数字在开头）
B2的值为156.86ACD，截取结果：156.86
输入公式：
=LOOKUP(9^9,LEFT(B2,ROW(1:9))*1)
2）数字提取（数字在结尾头）
B3的值为 ACD156.87截取结果：156.87
输入公式：
=LOOKUP(9^9,RIGHT(B3,ROW(1:9))*1)
3）数字提取（数字在任意位置）
B4的值为ACD156.88GH 截取结果：156.88
输入公式：
=LOOKUP(9^9,MID(B4,MATCH(1,MID(B4,ROW(1:9),1)^0,0),ROW(1:9))*1)
以上就是 LOOKUP 的11种经典用法，看似有些复杂，其实，很简单的，建议大家多看几遍然后动手练习。
以上就是今天分享的干货技巧，你Get到了吗？别忘记动手练习鸭~
office研习社，每天陪你学习一点点，进步一点点。
喜欢今天的文章，别忘记 「收藏」 点 「在看」 支持~
咱们下期再见！^_^
— END —
作者：细姐，Excel效率达人，用通俗易懂的方式帮你解决Excel问题。来源：office研习社（ID：office_360）关注我，提高工作效率早下班。
