小伙伴们好啊，今天咱们一起来学习XLOOKUP函数。
函数的常规用法为：
=XLOOKUP( 查找内容 ,一 行或一列的查找区域 ,要回传内容的区域)
如下图所示，要根据G3单元格中的姓名，在左侧数据区域中查询所属部门。
H3单元格公式为：
=XLOOKUP( G3 , D2:D7 , B2:B7 )
公式中的G3，是要查询的姓名，D2:D7是姓名所在的区域，B2:B7就是咱们要回传信息的区域了。
利用Excel 2021的自动溢出功能，下面这个公式可以同时获取部门、职务信息。
=XLOOKUP(G3,D2:D7,B2:C7)
如果要使用多个条件来查询，该怎么办呢？
如下图所示， 要根据G3和H3的姓名以及部门，来查询对应的职务，可以使用以下公式来实现：
=XLOOKUP( G3 & H3 , D2:D7 & B2:B7 , C2:C7 )
第一参数，把两个查询条件使用连接符合并到一起，第二参数把两个查询区域也合并到一起，就这么简单。
如果找不到指定的内容，咱们还可以使用第四参数让他返回指定的内容或者是其他的计算公式。
比如下面这个公式，在查找不到关键字时，就会返回指定的内容「找不到」。
=XLOOKUP( G3 , D2:D7 , B2:B7 ," 找不到 ")
在查询数值时，还可以使用第五参数来指定使用匹配方式。
如下图，要根据右侧的对照表，将E2单元格中的考核分变成对应的等级，可以使用以下公式：
=XLOOKUP(
E2
,
H:H
,
I:I
,,-1)
因为要使用近似匹配方式，所以不需要屏蔽错误值，这里XLOOKUP函数的第四参数省略就可以了。
第五参数可以使用0、1或是-1来指定不同的匹配方式，本例中使用-1，表示在H列中找不到E2单元格的值时，就以比E2小的最接近值来匹配。也就是在找不到66时，就以60来匹配，并返回I列对应的等级标准「巴结」。
如果要在第一参数中使用通配符来实现关键字的查询，第五参数需要写成2。
=XLOOKUP( G3 &"*", B2:B7 , D2:D7 ,,2)
如果查询区域中有多项符合条件的记录，还可以通过第6参数来指定返回第一个还是最后一个。
如下图所示，B列有两个采购部的记录，使用以下公式会以最后一个记录来匹配。
=XLOOKUP( G3 , B2:B7 , D2:D7 ," 找不到 ",,-1)
如果要以第一个记录匹配，这里的参数可以省略，或者使用1就好了。
使用XLOOKUP函数，还能够从二维表中查询数据。
如下图所示，要根据I2单元格的部门和I3单元格的月份，从左侧表格中查询对应的数值，可以使用以下公式。
=XLOOKUP( I2 , A2:A7 ,XLOOKUP( I3 , B1:G1 , B2:G7 ))
这个公式里，用到了两个XLOOKUP。
先来看
XLOOKUP(
I3
,
B1:G1
,
B2:G7
)
部分，目的是根据I3单元格的月份，在B1:G1单元格区域中查询到该月份，并返回B2:G7单元格对应的内容，得到的是「4月」所在列的全部数值：
最外层的XLOOKUP，以I2单元格中的部门为查询值，以A列作为查询区域，以第二个XLOOKUP返回的结果作为回传区域，最终在二维表中返回了咱们需要的结果。
图文制作：祝洪忠
