点击 👆 office研习社 👇 关注星标 ★ 不迷路
你好，我是小智。
Countif是单条件计数函数，在Excel函数界是一位低调大咖；
随着数据透视表的名气越来越大，它的基础功能看起来被替代了。
殊不知它的拓展功能也是实力雄厚，下面我们一起来学习吧~
1、基础应用
COUNTIF函数是条件计数函数，即根据指定条件统计数量，语法：=COUNTIF(条件区域,条件)，统计条件区域中符合条件的数量。
「 案例 」 统计单位为「北魏」的人员数量
「 公式 」 =COUNTIF(C2:C9,C2)
「 解析 」 统计C2： C9区域里面有几个C2。
2、条件计数
「 案 例 」 统计月薪高于5000的人数
「 公式 」 =COUNTIF(D2:D9,">5000")
「 解析 」 函数 里面 第二个参数用文本「>5000」表示，统计结果只计算大于5000的数据。
3、统计区间数量
「 案例 」 统计月薪在3000到 4000之间的人数
「 公式 」 =COUNTIF(D2:D9,">3000")-COUNTIF(D2:D9,">4000"）
「 解析 」 先统计大于3000的人数，再减去大于4000的人数，即为月薪在3000至4000的人数。
4、模糊统计
「 案例 」 统计人员姓名中姓「曹」的人数
「 公式 」 =COUNTIF(B2:B9,"曹*")
「 解析 」 这里面需要使用通配符「*」，可以代替任意一个或多个字符。
5、分组排列
「 案例 」 根据单位分别添加序号
「 公式 」 =COUNTIF($B$2:B2,B2)
「 解析 」 这里用到的是函数的绝对引用和相对引用，第一个参数条件区域的开始位置为绝对引用（锁定），结束位置为相对引用（未锁定），函数向下填充时这个区域不断扩大，才达到了分组添加序号的效果。
6、多个条件计数
「 案例 」 统计单位为「北魏」和「东吴」的人员数量
「 公式 」 =COUNTIF(C2:C9,{"北魏","东吴"})
「 解析 」 这里面是统计两个条件的数量，可以用常量数组{}来表示。
7、统计文本数量
「 案例 」 统计月薪 区域 有多少个文本 单元
「 公式 」 =COUNTIF(D2:D9,"*")
「 解析 」 这里面通配符「*」代表任意一个或多个文本字符。
8、统计非空单元格
「 案例 」 统计月薪区域区域有多少个空单元格
「 公式 」 =COUNTIF(D2:D9,"<>")
「 解析 」 这里面「<>」的意思是不等于空。
9、统计空单元格
「 案例 」 统计月薪区域区域有多少个空单元格
「 公式 」 =COUNTIF(D2:D9,"=")
「 解析 」 这里面「=」的意思是等于空。
10、统计不重复值
「 案例 」 统 计表格中的「单位」一共有几个唯一值
「 公式 」 =SUMPRODUCT(1/COUNTIF(C2:C9,C2:C9))
「 解析 」 这里分别统计每一项的出现次数，然后对其倒数进行求和。
11、中国式排名
「 案例 」 根据月薪由高到低进行中国式排名
「 公式 」 ：
= S UMPRODUCT(($D$2:$D$9>D2)*(1 /COUNTIF($D$2:$D$9,$D$2:$D$9)))+1
「 解析 」 中国式排名： 出现并列时，下一个接续排名，而不是实际排名。 公式还是先求出每个数值出现的次数的倒数，再与「是否比本身大「这个数组相乘相加，最后加1就是自己的排名。
13、提取不重复值
「 案例 」 将表格中「单位」列中的不重复值都提取出来，类似功能里面的删除重复项。
「 公式 」 ：
=IFERROR(INDEX($C$2:$C$9,MATCH(0,COUNTIF($E$1:E1,E$C$2:$C$9),0)),"")，数组公式需要按ctrl+shift+enter三键结束。
「 解析 」 总体思路是输入公式时一一确认每个公式之前的公式提取了哪项内容，没被提取过的显示0，再根据0在数组中的位置返回对应的值。
13、判断重复的身份证号
「 案例 」 判断身份证号是否重复
「 公式 」 =IF(COUNTIF($B$2:$B$7,B2&"*")>1,"重复","")
「 解析 」 这个公式并不复杂，只是最外面嵌套了一个IF函数，里面关键的是 「 &「*」 」 ，当countif统计超过15位的文本型数字时，只要前15位一致，就会被认为是相同的。 所以公式里连接一个*，变成纯文本进行判断。
以上就是今天分享的干货技巧，你Get到了吗？
office研习社，每天陪你学习一点点，进步一点点。
喜欢今天的文章，别忘记 「收藏」 点 「在看」 支持~
咱们下期再见！ ^_^
— END —
©作者：细姐，Excel效率达人，用通俗易懂的方式帮你解决Excel问题。来源：office研习社（ID：office_360）关注我，提高工作效率早下班。
