點選 👆 office研習社 👇 關註星標 ★ 不迷路
你好，我是小智。
前段時間給同學們介紹過Looku p函式的基本用法，相信大家都有所了解了。
其實，在Excel尋找函式中，Lookup的尋找功能超級強大，它可以實作很多Vlookup無法完成的尋找。
今天我帶大家一起盤點一下它的11種最經典用法。
1、 普通尋找（已排序）
如果表格已按A列排序，可以直接用Lookup尋找。
尋找李偉所在的部門。
輸入公式： =LOOKUP(E2,A2:A7,C2:C7)
2、 普通尋找（未排序）
A列未排序的表格，就需要用0/的方法完成尋找。
尋找李偉所在的部門
輸入公式：
=LOOKUP(1,0/(A2:A7=E2),C2:C7)
3、 尋找最後
1）尋找最後一個非數位字元
用一個漢字裏排序靠後的「座」尋找即可，當然你也可以用排序更後的生僻字，只是用的時候你很難打出來。
尋找A列最後一個非數位字元
輸入公式： =LOOKUP("座",A:A)
2）尋找最後一個數位
用一個足夠大的數位9E307即可。
尋找B列最後一個數位
輸入公式： =LOOKUP(9E+307,B:B)
3）尋找最後一個非空內容
還是需要用0/模式尋找
尋找A列最後一個非空內容
輸入公式：
=LOOKUP(1,0/(A1:A28<>""),A1:A28)
4）根據條件尋找最後一個
公式和普通尋找一樣，但有多個符合條件時，lookup只會返回最後一個。
尋找西瓜最後一次數量
輸入公式：
=LOOKUP(1,0/(A2:A7=D2),B2:B7)
4、 區間尋找
只要 數位已排序 ，可以進行區間匹配尋找。
根據D2的銷量尋找對應區間提成
輸入公式： =LOOKUP(D2,A:B)
5、 多條件尋找
只需要在0/模式中多加條件即可
尋找湖南的西瓜數量
輸入公式： =LOOKUP(1,0/((B2:B7=F2)*(A2:A7=E2)),C2:C7)
6、 反向尋找
根據部門尋找姓名：
輸入公式： =LOOKUP(F2,D2:D7,A2:A7)
7、 連續多列尋找
輸入公式： =LOOKUP($F2,$A:B)
8、 根據簡稱查全稱
要借用find函式實作
如下圖所示，要求根據資訊表從上表中尋找我的公眾號全稱。
輸入公式：
=LOOKUP(9^9,FIND(A8,B2:B5),A2:A5)
9、 根據全稱查簡稱
如下圖所示，要求根據資訊表從上表中尋找培哥學堂的的關鍵詞。
輸入公式：
=LOOKUP(9^9,FIND(A10,A2:A5),B2:B5)
10、 包含尋找
從給定的多個關鍵字中，從字串中尋找包括其中一個
現需要在B列把公眾號全稱的關鍵詞分別提取出來，關鍵詞有：小何、培哥、講師、指南
輸入公式：
=LOOKUP(9^9,FIND({"小何","培哥","講師","指南"},A2),{"小何","培哥","講師","指南"})
11、 數位提取
1）數位提取（數位在開頭）
B2的值為156.86ACD，截取結果：156.86
輸入公式：
=LOOKUP(9^9,LEFT(B2,ROW(1:9))*1)
2）數位提取（數位在結尾頭）
B3的值為 ACD156.87截取結果：156.87
輸入公式：
=LOOKUP(9^9,RIGHT(B3,ROW(1:9))*1)
3）數位提取（數位在任意位置）
B4的值為ACD156.88GH 截取結果：156.88
輸入公式：
=LOOKUP(9^9,MID(B4,MATCH(1,MID(B4,ROW(1:9),1)^0,0),ROW(1:9))*1)
以上就是 LOOKUP 的11種經典用法，看似有些復雜，其實，很簡單的，建議大家多看幾遍然後動手練習。
以上就是今天分享的幹貨技巧，你Get到了嗎？別忘記動手練習鴨~
office研習社，每天陪你學習一點點，進步一點點。
喜歡今天的文章，別忘記 「收藏」 點 「在看」 支持~
咱們下期再見！^_^
— END —
作者：細姐，Excel效率達人，用通俗易懂的方式幫你解決Excel問題。來源：office研習社（ID：office_360）關註我，提高工作效率早下班。
